R:= RootSystem( "G",2);
 U:=QuantizedUEA(R); 
 g:= GeneratorsOfAlgebra( U ); 
 PositiveRoots(R); 
 PositiveRootsInConvexOrder(R); 
########## generators of U ###############
 f1:=g[1]; f2:=g[6]; e1:=g[11]; e2:=g[16];
 k1:=g[7]; k1m:=g[8]; k2:=g[9]; k2m:=g[10];
########## generators of Uq'(k) ###############
 b1:=f1-k1m*e1;
 b2:=f2-k2m*e2;
########## q-numbers #################### 
 2q:=_q+_q^-1;
 2q2:=_q^2+_q^-2;
 2q3:= _q^3+_q^-3;
 3q:=_q^2+1+_q^-2;
 4q:=_q^3+_q+_q^-1+_q^-3;
 5q:=_q^4+_q^2+ 1 +_q^-2+_q^-4;
######### relations in Uq'(k) as a function #########
 rel1:=function(a,b)
   return a^2*b - 2q3*a*b*a + b*a^2 +_q^-3 *b;
 end;
 rel2:=function(a,b)
   return b^4*a - 4q *b^3*a*b + 3q* 2q2*  b^2*a*b^2 - 4q*b*a*b^3 + a*b^4
        + _q^-1 * (3q^2+1)*(b^2*a+a*b^2) - _q^-1*2q *(2q*4q+2q2)* b*a*b + _q^-2* 3q^2* a;
 end;
########################################
 rel1(b2,b1);
 rel2(b2,b1);
######## images of generators under tau_1^{-1} and tau_2^{-1} ##########
 tau2mb2:=b2;;
 tau2mb1:=b2*b1-_q^3*b1*b2;;
 tau1mb1:=b1;;
 tau1mb2:=3q^-1 * 2q^-1*( b1^3 * b2 - _q*3q *b1^2*b2*b1 + _q^2 * 3q *b1*b2*b1^2 -_q^3 *b2 *b1^3 
            + _q^-1* (b1*b2 - _q^3* b2*b1)) + (b1*b2 - _q* b2*b1);;
######## tau1m and tau2m are algebra automorphisms ######################
rel1(tau2mb2,tau2mb1);
rel2(tau2mb2,tau2mb1);
rel1(tau1mb2,tau1mb1);
rel2(tau1mb2,tau1mb1);
####### definition of tau1 and tau2 #####################
 tau2b2:=b2;;
 tau2b1:=b1*b2-_q^3*b2*b1;;
 tau1b1:=b1;;
 tau1b2:=3q^-1 * 2q^-1*( b2 * b1^3 - _q*3q *b1*b2*b1^2 + _q^2 * 3q *b1^2*b2*b1 -_q^3 *b1^3 * b2 
           + _q^-1* (b2*b1 - _q^3* b1*b2)) + (b2*b1 - _q* b1*b2);;
######## tau1 and tau2 are algebra automs ######################
rel1(tau2b2,tau2b1);
rel2(tau2b2,tau2b1);
rel1(tau1b2,tau1b1);
rel2(tau1b2,tau1b1);
######### tau1m is the inverse of tau1 ########################
 tau1mb1 -b1;
 3q^-1 * 2q^-1*( tau1mb2 * tau1mb1^3 - _q*3q *tau1mb1*tau1mb2*tau1mb1^2 + _q^2 * 3q *tau1mb1^2*tau1mb2*tau1mb1 -_q^3 *tau1mb1^3 * tau1mb2 + _q^-1* (tau1mb2*tau1mb1 - _q^3* tau1mb1*tau1mb2)) + (tau1mb2*tau1mb1 - _q* tau1mb1*tau1mb2) -b2;
tau1b1-b1;
 3q^-1 * 2q^-1*( tau1b1^3 * tau1b2 - _q*3q *tau1b1^2*tau1b2*tau1b1 + _q^2 * 3q *tau1b1*tau1b2*tau1b1^2 -_q^3 *tau1b2 *tau1b1^3 + _q^-1* (tau1b1*tau1b2 - _q^3* tau1b2*tau1b1)) + (tau1b1*tau1b2 - _q* tau1b2*tau1b1) -b2;
######### tau2m is inverse of tau2 ########################
tau2b2-b2;
tau2b2*tau2b1-_q^3*tau2b1*tau2b2 - b1;
tau2mb2-b2;
tau2mb1*tau2mb2-_q^3*tau2mb2*tau2mb1 - b1;
###############################################################
######## Towards the braid relation ##################################
#### The following calculations should verify the braid relations ####
#### for tau1 and tau2. Unfortunately GAP crashes during these    ####
#### calculations. We asked Istvan Heckenberger to check the      #### 
#### braid relations using the noncommutative algebra programme   ####
#### FELIX. With FELIX the braid relations were verified quickly. ####
######################################################################
tau12:=tau2mb1;
tau21:=tau1mb2;
tau121:= tau12*b1-_q^3*b1*tau12;
tau212:= 3q^-1 * 2q^-1*( tau21^3 * b2 - _q*3q *tau21^2*b2*tau21 + _q^2 * 3q *tau21*b2*tau21^2 -_q^3 *b2 *tau21^3 + _q^-1* (tau21*b2 - _q^3* b2*tau21)) + (tau21*b2 - _q* b2*tau21);
tau2121:= tau212*tau21-_q^3*tau21*tau212;
tau1212:= 3q^-1 * 2q^-1*( tau121^3 * tau12 - _q*3q *tau121^2*tau12*tau121 + _q^2 * 3q *tau121*tau12*tau121^2 -_q^3 *tau12 *tau121^3 + _q^-1* (tau121*tau12 - _q^3* tau12*tau121)) + (tau121*tau12 - _q* tau12*tau121);
tau12121:= tau1212*tau121-_q^3*tau121*tau1212;
tau21212:= 3q^-1 * 2q^-1*( tau2121^3 * tau212 - _q*3q *tau2121^2*tau212*tau2121 + _q^2 * 3q *tau2121*tau212*tau2121^2 -_q^3 *tau212 *tau2121^3 + _q^-1* (tau2121*tau212 - _q^3* tau212*tau2121)) + (tau2121*tau212 - _q* tau212*tau2121);
tau212121:= tau21212*tau2121-_q^3*tau2121*tau21212;
tau121212:= 3q^-1 * 2q^-1*( tau12121^3 * tau1212 - _q*3q *tau12121^2*tau1212*tau12121 + _q^2 * 3q *tau12121*tau1212*tau12121^2 -_q^3 *tau1212 *tau12121^3 + _q^-1* (tau12121*tau1212 - _q^3* tau1212*tau12121)) + (tau12121*tau1212 - _q* tau1212*tau12121);
tau1212121:= tau121212*tau12121-_q^3*tau12121*tau121212;
tau2121212:= 3q^-1 * 2q^-1*( tau212121^3 * tau21212 - _q*3q *tau212121^2*tau21212*tau212121 + _q^2 * 3q *tau212121*tau21212*tau212121^2 -_q^3 *tau21212 *tau212121^3 + _q^-1* (tau212121*tau21212 - _q^3* tau21212*tau212121)) + (tau212121*tau21212 - _q* tau21212*tau212121);
######## braid relations #################################
tau1212121-tau212121;
tau2121212-tau121212;
#############################################################
############ Relation to Lusztig automorphisms       ########
############ Here we check Equation (3.2) for aij=-3 ########
#############################################################
tau:=AntiAutomorphismTau( U );
T1:=AutomorphismTalpha(U,1);
T2:=AutomorphismTalpha(U,2);
T1m:= tau*T1*tau;
T2m:= tau*T2*tau;
######## the error terms ##################################
E3m:=-(_q-_q^-1) * ( (2q^-1 * f1^2 *f2 - _q^2 * f1 * f2 * f1 + _q^4 * 2q^-1 * f2 * f1^2)*k1m * e1 +  (f1 * f2 - _q^3 * f2 * f1) * (_q^-1 *k1m^2 + (_q^2 -1) * k1m^2 * e1^2) + _q^-1 * (_q^3 -_q^-3) *f2 * k1m^3 *e1 +_q^3 * (_q - _q^-1)^2 *f2 * k1m^3 * e1^3);
Image(T1m,b2) - tau1mb2 - E3m;
######## :-) End :-) #####################################